Warning

You are reading the documentation for an older Pickit release (3.0). Documentation for the latest release (3.3) can be found here.

Fanuc example picking program

This article describes the Fanuc example picking program. Then, it explains how to adapt the program to start running it. It is ideal to get started with Pickit.

PICKIT_SIMPLE_PICKING: program overview

The program follows the generic Pickit example program logic.

First check if Pickit is in Robot mode.
If so, the robot moves to its detect pose and a detection is triggered.
If an object is found and if it is reachable, the robot moves to the object to pick it. Next, the robot moves to a fixed drop off position. During these motions when the robot is out the field of view of the camera, a new Pickit detection is triggered immediately.
If the ROI is empty, the program stops.
If no object is found but ROI is not empty, a Snapshots is saved on the Pickit system and the robot program stops.

This program can be found in Select.

Note

The program presented here is for recent controllers (R-30iB and R-30iB plus). For the older R-30iA controller, another program called PICKIT_SIMPLE_PICKING_V7 is available. The program is the same, but uses JUMP statements instead of the IF ELSE statements (not supported in this older version).

Tip

For fixed camera setups, it is recommended to replace the consecutive calls to PI_CAPTURE_IMAGE and PI_PROCESS_IMAGE by a call to PI_LOOK_FOR_OBJECT. That way the robot program will not wait for the image to be captured to continue.

 !Program settings ;
 !Fill in settings below ;
 UFRAME_NUM=0 ;
 UTOOL_NUM=1 ;
 R[1:setup id]=3    ;
 R[2:product id]=2    ;
 R[3:max detect]=5    ;
 R[4:pre offset]=(-100)    ;
 R[5:post offset]=(-100)    ;
  ;
  ;
 !Init ;
 CALL PI_OPEN_COMMUNICATION    ;
 CALL PI_RUN    ;
 IF (R[151:pi status]<>0) THEN ;
 MESSAGE[Not in robot mode] ;
 JMP LBL[2] ;
 ENDIF ;
 CALL PI_CONFIGURE(R[1:setup id],R[2:product id]) ;
 CALL PI_SET_OFFSET(R[4:pre offset],1) ;
 CALL PI_SET_OFFSET(R[5:post offset],2) ;
  ;
 !First detection ;
J P[1:detect] 100% CNT100    ;
 CALL PI_DETECTION_WITH_RETRIES(R[3:max detect]) ;
 CALL PI_GET_RESULT    ;
  ;
  ;
 !Main Loop ;
 LBL[1] ;
  ;
 !If object found ;
 IF (R[150:pi obj status]=20) THEN ;
  ;
 !If reachable ;
 CALL PI_REACH    ;
 IF (R[160:pi reach status]=0) THEN ;
  ;
 !Picking ;
J P[2:above bin] 100% CNT100    ;
 !Move to pre pick pose ;
L PR[51:pi pick pose] 100mm/sec CNT100 Tool_Offset,PR[1:pre offset]    ;
 !Move to pick pose ;
L PR[51:pi pick pose] 100mm/sec FINE    ;
 !Add grasping logic ;
 !Move to post pick pose ;
L PR[51:pi pick pose] 100mm/sec CNT100 Tool_Offset,PR[2:post offset]    ;
L P[2:above bin] 100mm/sec CNT100    ;
 !Detection ;
J P[1:detect] 100% CNT100    ;
 CALL PI_CAPTURE_IMAGE    ;
 CALL PI_PROCESS_IMAGE    ;
  ;
 !Drop off ;
J P[3:drop off] 100% FINE    ;
 !Add release logic ;
J P[1:detect] 100% CNT100    ;
  ;
 !Get detection results ;
 CALL PI_GET_RESULT    ;
  ;
 !Not reachable ;
 ELSE ;
 !Try next object ;
 CALL PI_NEXT_OBJECT    ;
 CALL PI_GET_RESULT    ;
 ENDIF ;
  ;
 !No object found ;
 ELSE ;
 !Empty ROI ;
 IF (R[150:pi obj status]=23) THEN ;
 MESSAGE[ROI is empty] ;
 JMP LBL[2] ;
 !No object found ;
 ELSE ;
 MESSAGE[No object found] ;
 CALL PI_SAVE_SCENE    ;
 JMP LBL[2] ;
 ENDIF ;
 ENDIF ;
 JMP LBL[1] ;
 LBL[2] ;
   END

See Pickit macros for more information about the Pickit rountines available.

Before running the program

This example program requires Pickit to be installed and set up with your robot. For installation instructions, please refer to the Fanuc installation and setup article.

Make sure that Calibration is done. This can be done by running the Fanuc calibration program.

Run PI_SET_PICK_POSE

Before executing the picking program we first need to define the robot joint configuration for picking. This is done by jogging the robot to the center of the picking area and manually run the PI_SET_PICK_POSE macro. The macro will read out the current joint configuration of the robot and this will be used as seed for all calculated pick poses.

Define the tool for picking

Create a tool frame with the actual TCP values. In this example UTOOL1 is used.

Adapt the registers used in PICKIT_SIMPLE_PICKING

Below you find an overview of the registers used in this example program. They should be adapted according the changes you want to apply to this example program.

Note

The Pickit registers, in the 140-160 range, and the Pickit pose registers, in the 50 range, can’t be changed by the user. An overview of these can be found in the Fanuc Pickit interface article.

Variable	Field name	Comment
R[1]	Setup	Requested Pickit setup ID
R[2]	Product	Requested Pickit product ID
R[3]	Retries	Maximum number of detection retries
R[4]	Pre pick offset	Z offset used to defined the pre pick pose offset (use a negative value).
R[5]	Post pick offset	Z offset used to defined the post pick pose offset (use a negative value).
P[1]	Detect pose	Position not blocking the field of view of the camera when triggering detections
P[2]	Above bin pose	Position above the picking area
P[3]	Drop off pose	Position where the object is dropped off
PR[1]	Pre pick pose	Position offset the robot moves to before picking the object (relative to tool frame)
PR[2]	Post pick pose	Position offset the robot moves to after picking the object (relative to tool frame)

Add grasping/releasing logic

At the pi pose and drop off pose positions, grasping and releasing logic needs to be added, respectively.

Execute the picking program

Now you can run the program. Happy picking!